用批处理代码程序把笔记本变成无线WIFI热点，支持win8

@echo off
TITLE 无线热点共享 By:Michael
 
 
cls
::color 2f是颜色显示，用两个16进制数表示，其中第一个数为背景色，第二个数为前景色。如果想要查看更多请在cmd里输入color /? 并回车即可查看，更改数字就可以修改显示颜色
color 0A
mode con: cols=42 lines=29
 
 
goto check_Permissions
 
:check_Permissions
 
    net session >nul 2>&1
    if %errorLevel% == 0 (
        goto start
        ) else (
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋   请以管理员身份运行此程序   ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
        pause >nul
       )
 
:start
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋ 请选择要进行的操作然后按回车 ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋                              ┋
echo     ┋         1. 开启热点          ┋
echo     ┋                              ┋
echo     ┋         2. 发射信号          ┋
echo     ┋                              ┋
echo     ┋         3. 一键设置          ┋
echo     ┋                              ┋
echo     ┋         4. 关闭信号          ┋
echo     ┋                              ┋
echo     ┋         5. 关闭热点          ┋
echo     ┋                              ┋
echo     ┋         6. 重置密码          ┋
echo     ┋                              ┋
echo     ┋         7. 重置名称          ┋
echo     ┋                              ┋
echo     ┋         8. 网络信息          ┋
echo     ┋                              ┋
echo     ┋         9. 使用帮助          ┋
echo     ┋                              ┋
echo     ┋         0. 退出程序          ┋
echo     ┋                              ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:ch
set Choice=
set /p Choice=选择操作并回车:
if not "%Choice%"=="" set Choice=%Choice:~0,1%
echo.
	IF /I "%Choice%"=="1" GOTO 1
	IF /I "%Choice%"=="2" GOTO 2
	IF /I "%Choice%"=="3" GOTO 3
	IF /I "%Choice%"=="4" GOTO 4
	IF /I "%Choice%"=="5" GOTO 5
	IF /I "%Choice%"=="6" GOTO 6
	IF /I "%Choice%"=="7" GOTO 7
	IF /I "%Choice%"=="8" GOTO 8
	IF /I "%Choice%"=="9" GOTO 9
	IF /I "%Choice%"=="0" GOTO end
echo 选择无效，请重新输入
echo.
goto ch
 
:1
:: 开启热点
cls
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋  继  续  设  置  请  按   1  ┋
echo     ┋  返  回  菜  单  请  按   2  ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:back1
set ask=
set /p ask=选择:
echo.
if /i "%ask%"=="1" goto SHE
if /i "%ask%"=="2" goto start
echo 选择无效，请重新输入
echo.
goto back1
:SHE
echo.
netsh wlan set hostednetwork mode=allow
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋  请  设  置  热  点  名  称  ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:and
echo.
set ssid=
set /p ssid=请重置热点名称：
echo.
if "%ssid%"=="" goto and
netsh wlan set hostednetwork ssid=%ssid%
set ssid=
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋  请  设  置  热  点  密  码  ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:again
echo.
set key=0
set /p key=请设置8位以上的密码：
echo.
if "%key:~7,1%"==""  echo 密码不足8位&goto again
netsh wlan set hostednetwork key=%key%
set key=
::是否发射信号
cls
echo.
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo     ┋  确  认  发  射  请  按   1  ┋
echo     ┋  暂  不  发  射  请  按   2  ┋
echo     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:back2
set ask=
set /p ask=选择:
echo.
if /i "%ask%"=="1" goto 2
if /i "%ask%"=="2" goto tishi
echo 选择无效，请重新输入
echo.
goto back2
:tishi
cls
color 0c
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋ 您 选 择 了 暂 时 不 发  射 信 号┋
echo   ┋ 如 果 您 想 发 射 信 号，请 在 主┋
echo   ┋ 菜 单 中 选 择“2.发射信号”即 可┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
 
:2
::发射信号
cls
netsh wlan start hostednetwork
echo.
echo    ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo    ┋                                ┋
echo    ┋ 已     发     射     信     号 ┋
echo    ┋ 请     连     接     设     备 ┋
echo    ┋                                ┋
echo    ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
::一键设置
:3
cls
::如果你不想每次都进入第一步设置名称密码，可以用自己设置好的默认设置，修改以下两行即可
::其中ssid为热点名称；key为密码（不得少于8位）。这样设置之后，每次使用时进入第3步即可！
set ssid=WIFI
set /a key=1234567890
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key%
netsh wlan start hostednetwork
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋                                  ┋
echo   ┋    设      置      成      功    ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
echo ━━━━━━━━━━━━━━━━━━━━━
echo  热点默认名称为: %ssid%
echo.
echo  热点默认密码为: %key%
echo.
echo ━━━━━━━━━━━━━━━━━━━━━
set ssid=
set key=
echo.
pause
goto start
 
:4
::关闭信号
cls
color 0c
netsh wlan stop hostednetwork
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋       已 停 止 发 射 信 号       ┋
echo   ┋     ------------------------     ┋
echo   ┋ 如 果 想 再 次 开 启 热 点 请 重 ┋
echo   ┋ 新 设 置 第  1 步 或 者 第  3 步 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
:5
::关闭热点
cls
color 0c
netsh wlan set hostednetwork mode=disallow
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋      已   关   闭   热   点      ┋
echo   ┋     -----------------------      ┋
echo   ┋ 如 果 想 再 次 开 启 热 点 请 重 ┋
echo   ┋ 新 设 置 第  1 步 或 者 第  3 步 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
:6
:: 重置密码
cls
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋                                  ┋
echo   ┋ 请   重   置   热   点   密   码 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
:begin
echo.
set key=0
set /p key=请重置8位以上的密码：
echo.
if "%key:~7,1%"==""  echo 密码不足8位&goto begin
::if "%key:~13,1%" neq "" echo 超过13位&goto begin
netsh wlan set hostednetwork key=%key%
set key=
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋                                  ┋
echo   ┋ 已   重   置   热   点   密   码 ┋
echo   ┋ 请   重   新   连   接   设   备 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
:7
:: 重置名称
cls
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋                                  ┋
echo   ┋ 请   重   置   热   点   名   称 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:an
echo.
set /p ssid=请重置热点名称：
echo.
if "%ssid%"=="" goto an
netsh wlan set hostednetwork ssid=%ssid% 
netsh wlan start hostednetwork
set ssid=
echo.
echo   ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo   ┋                                  ┋
echo   ┋ 已   重   置   热   点   名   称 ┋
echo   ┋ 请   重   新   连   接   设   备 ┋
echo   ┋                                  ┋
echo   ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo.
pause
goto start
 
:8
::网络信息显示
cls
mode con: cols=48 lines=30
echo.
echo  ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo  ┋  网     络     信      息     显     示  ┋
echo  ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo ------------------------------------------------
netsh wlan show hostednetwork
echo ------------------------------------------------
echo  ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo  ┋提示：客户端数是指外界设备连接本热点的个数┋
echo  ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
pause
goto start
 
:9
::使用说明
cls
color 3f
mode con: cols=70 lines=32
echo.
echo  ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo  ┋        程        序       使       用       说       明        ┋
echo  ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo  ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo  ┋1.使用此程序前请设置好计算机网络共享！此程序在windows7/windows8 ┋
echo  ┋  系统下测试可用。电脑需配置有无线网卡，并需支持承载网络。      ┋
echo  ┋----------------------------------------------------------------┋
echo  ┋2.第1、3步的区别：每次使用热点时都需要设置第1或第3步。其中第1步 ┋
echo  ┋  需要每次分别为热点设置名称和密码；而第3步为默认设置，已经在程 ┋
echo  ┋  序中定好，只需一步便可发射信号。为了方便，以后建议使用一键设置┋
echo  ┋  其中默认名称为WIFI，密码为1234567890。若想更改默认名称及密码，┋
echo  ┋  可用记事本打开方式打开此程序进入代码中的“::一键设置”部分修改┋
echo  ┋  其中两行即可（代码中有修改说明）                              ┋
echo  ┋----------------------------------------------------------------┋
echo  ┋3.名称建议用字母和数字，请尽量不用复杂的符号，否则系统可能不识别┋
echo  ┋----------------------------------------------------------------┋
echo  ┋4.密码请设置8位数以上，请尽量不用复杂的符号， 否则系统可能不识别┋
echo  ┋----------------------------------------------------------------┋
echo  ┋5.第4、5步区别：第4步为“已停止承载网络”，若进入网络信息会看到 ┋
echo  ┋  “承载网络状态”为未启用；第5步为“承载网络模式已设置为禁止” ┋
echo  ┋  进入网络信息会看到“承载网络状态”为不可用。不用热点的时候选择┋
echo  ┋  第4或第5步都可。若之后想继续使用无线发射，需再次设置第1或第3步┋
echo  ┋----------------------------------------------------------------┋
echo  ┋6.计算机关机或重启等也会自动关闭无线热点，故启动电脑后若想使用无┋
echo  ┋  线发射，需再次设置第1步或者第3步。如需要更改密码或名称，可在主┋
echo  ┋  菜单选择第6步或第7步进行更改，然后在接收设备上重新连接即可。  ┋
echo  ┋----------------------------------------------------------------┋
echo  ┋7.若出现搜索到信号但连接不了或上不了网的情况，那么重新设置第1步 ┋
echo  ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo 请按任意键返回主菜单...
pause >nul
goto start
 
:end
exit